gentoo-karlay

My Gentoo ebuild overlay
Log | Files | Refs

profanity-0.14.0-r3.ebuild (2583B)

      1 # Copyright 1999-2025 Gentoo Authors
      2 # Distributed under the terms of the GNU General Public License v2
      3 
      4 EAPI=8
      5 
      6 PYTHON_COMPAT=( python3_{10..13} )
      7 inherit flag-o-matic python-single-r1
      8 
      9 DESCRIPTION="A console based XMPP client inspired by Irssi"
     10 HOMEPAGE="https://profanity-im.github.io"
     11 SRC_URI="
     12 	https://github.com/profanity-im/profanity/releases/download/${PV}/${P}.tar.gz
     13 	https://github.com/profanity-im/profanity/commit/122434a.patch
     14 		-> ${PN}-0.14.0-ox-carbons.patch
     15 	https://github.com/profanity-im/profanity/commit/2ed6211c.patch
     16 		-> ${PN}-0.14.0-xscreensaver.patch
     17 	https://github.com/profanity-im/profanity/commit/b8817470.patch
     18 		-> ${PN}-0.14.0-plugins-install.patch
     19 	https://github.com/profanity-im/profanity/commit/6b9d0e86.patch
     20 		-> ${PN}-0.14.0-fix-test-lto.patch
     21 "
     22 
     23 LICENSE="GPL-3"
     24 SLOT="0"
     25 KEYWORDS="amd64 ~arm64"
     26 IUSE="libnotify omemo omemo-qrcode otr gpg test xscreensaver python gtk gdk"
     27 RESTRICT="!test? ( test )"
     28 REQUIRED_USE="omemo-qrcode? ( omemo ) python? ( ${PYTHON_REQUIRED_USE} )"
     29 
     30 RDEPEND="
     31 	dev-db/sqlite:3
     32 	dev-libs/glib:2
     33 	>=dev-libs/libstrophe-0.12.3:=
     34 	media-libs/harfbuzz:=
     35 	net-misc/curl
     36 	sys-libs/ncurses:=[unicode(+)]
     37 	sys-libs/readline:=
     38 	x11-libs/cairo
     39 	gdk? ( x11-libs/gdk-pixbuf:2 )
     40 	gtk? ( x11-libs/gtk+:3 )
     41 	x11-libs/pango
     42 	x11-misc/shared-mime-info
     43 	gpg? ( app-crypt/gpgme:= )
     44 	libnotify? ( x11-libs/libnotify )
     45 	omemo? (
     46 		dev-libs/libgcrypt:=
     47 		net-libs/libsignal-protocol-c
     48 	)
     49 	omemo-qrcode? ( media-gfx/qrencode:= )
     50 	otr? ( net-libs/libotr )
     51 	python? ( ${PYTHON_DEPS} )
     52 	xscreensaver? (
     53 		x11-libs/libXScrnSaver
     54 		x11-libs/libX11
     55 	)
     56 "
     57 DEPEND="
     58 	${RDEPEND}
     59 	test? ( dev-util/cmocka )
     60 	python? (
     61 		$(python_gen_cond_dep '
     62 			dev-python/cython[${PYTHON_USEDEP}]
     63 		')
     64 	)
     65 "
     66 
     67 PATCHES=(
     68 	"${DISTDIR}/${PN}-0.14.0-ox-carbons.patch"
     69 	"${DISTDIR}/${PN}-0.14.0-xscreensaver.patch"
     70 	"${DISTDIR}/${PN}-0.14.0-plugins-install.patch"
     71 	"${DISTDIR}/${PN}-0.14.0-fix-test-lto.patch"
     72 )
     73 
     74 pkg_setup() {
     75 	use python && python-single-r1_pkg_setup
     76 }
     77 
     78 src_configure() {
     79 	# -Werror=lto-type-mismatch
     80 	# https://bugs.gentoo.org/932874
     81 	# https://github.com/profanity-im/profanity/issues/1992
     82 	filter-lto
     83 
     84 	local myeconfargs=(
     85 		$(use_enable gtk icons-and-clipboard)
     86 		$(use_enable gdk gdk-pixbuf)
     87 		$(use_enable libnotify notifications)
     88 		$(use_enable omemo)
     89 		$(use_enable omemo-qrcode)
     90 		$(use_enable otr)
     91 		$(use_enable python python-plugins)
     92 		$(use_enable gpg pgp)
     93 		$(use_with xscreensaver)
     94 	)
     95 
     96 	econf "${myeconfargs[@]}"
     97 }
     98 
     99 src_compile() {
    100 	emake CFLAGS="${CFLAGS}"
    101 }
    102 
    103 src_install() {
    104 	default
    105 
    106 	find "${ED}" -type f -name '*.la' -delete || die
    107 }