blob: 1ee38e8cd0160a25853ee98930ec79fcaec0423b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
|
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
(define-module (gnu services hurd)
#:use-module (gnu packages admin)
#:use-module (gnu packages hurd)
#:use-module (gnu services)
#:use-module (gnu services shepherd)
#:use-module (gnu system)
#:use-module (gnu system shadow)
#:use-module (guix gexp)
#:use-module (guix records)
#:export (hurd-console-configuration
hurd-console-service-type
hurd-getty-configuration
hurd-getty-service-type
hurd-login-configuration
hurd-login-service-type))
;;; Commentary:
;;;
;;; This module implements services for the Hurd.
;;;
;;; Code:
;;;
;;; The Hurd VGA console service.
;;;
(define-record-type* <hurd-console-configuration>
hurd-console-configuration make-hurd-console-configuration
hurd-console-configuration?
(hurd hurd-console-configuration-hurd ;file-like
(default hurd)))
(define (hurd-console-shepherd-service config)
"Return a <shepherd-service> for a Hurd VGA console with CONFIG."
(define console-command
#~(list
(string-append #$(hurd-console-configuration-hurd config) "/bin/console")
"-c" "/dev/vcs"
"-d" "vga"
"-d" "pc_kbd"
"-d" "generic_speaker"))
(list (shepherd-service
(documentation "Run the Hurd’s VGA console client.")
(provision '(console))
(requirement '(user-processes))
(start #~(make-forkexec-constructor #$console-command))
(stop #~(make-kill-destructor)))))
(define hurd-console-service-type
(service-type
(name 'console)
(description "Run the Hurd console client.")
(extensions
(list (service-extension shepherd-root-service-type
hurd-console-shepherd-service)))
(default-value (hurd-console-configuration))))
;;;
;;; The Hurd getty service.
;;;
(define-record-type* <hurd-getty-configuration>
hurd-getty-configuration make-hurd-getty-configuration
hurd-getty-configuration?
(hurd hurd-getty-configuration-hurd ;file-like
(default hurd))
(tty hurd-getty-configuration-tty) ;string
(baud-rate hurd-getty-configuration-baud-rate
(default 38400))) ;integer
(define (hurd-getty-shepherd-service config)
"Return a <shepherd-service> for a Hurd getty with CONFIG."
(let ((hurd (hurd-getty-configuration-hurd config))
(tty (hurd-getty-configuration-tty config))
(baud-rate (hurd-getty-configuration-baud-rate config)))
(define getty-command
#~(list
(string-append #$hurd "/libexec/getty")
#$(number->string baud-rate)
#$tty))
(list
(shepherd-service
(documentation "Run getty on a tty.")
(provision (list (string->symbol (string-append "term-" tty))))
(requirement '(user-processes console))
(start #~(make-forkexec-constructor #$getty-command))
(stop #~(make-kill-destructor))))))
(define hurd-getty-service-type
(service-type
(name 'getty)
(extensions (list (service-extension shepherd-root-service-type
hurd-getty-shepherd-service)))
(description
"Provide console login using the Hurd @command{getty} program.")))
;;;
;;; Hurd login service
;;;
(define-record-type* <hurd-login-configuration>
hurd-login-configuration make-hurd-login-configuration
hurd-login-configuration?
(hurd hurd-login-configuration-hurd ;file-like
(default hurd)))
(define (hurd-login-accounts config)
(let ((hurd (hurd-login-configuration-hurd config)))
(list (user-group
(name "login")
(system? #t))
(user-account
(name "login")
(group "login")
(system? #t)
(comment "login user")
(home-directory "/etc/login")
(shell (file-append hurd "/bin/loginpr"))))))
(define hurd-login-service-type
(service-type
(name 'login)
(extensions (list (service-extension account-service-type
hurd-login-accounts)))
(description
"Provide the login user for use by the Hurd @command{login} command.")
(default-value (hurd-login-configuration))))
;;; hurd.scm ends here
|
