build: Reject or warn against file name length limit overruns.

* m4/guix.m4 (GUIX_TEST_ROOT_DIRECTORY, LINUX_HASH_BANG_LIMIT,
  SOCKET_FILE_NAME_LIMIT, GUIX_SOCKET_FILE_NAME_LENGTH,
  GUIX_TEST_SOCKET_FILE_NAME_LENGTH, GUIX_HASH_BANG_LENGTH,
  GUIX_CHECK_FILE_NAME_LIMITS): New macros.
* configure.ac: Use 'GUIX_CHECK_FILE_NAME_LIMITS'.
* config-daemon.ac: Use 'GUIX_TEST_ROOT_DIRECTORY'.
* test-env.in: Check socket name length and emit warning if it exceeds
  107.

4 files changed, 69 insertions, 5 deletions

diff --git a/config-daemon.ac b/config-daemon.ac
index 32520acbf23..5f83d45a4cb 100644
--- a/config-daemon.ac
+++ b/config-daemon.ac
@@ -127,9 +127,8 @@ if test "x$guix_build_daemon" = "xyes"; then
   fi
 
   dnl Temporary directory used to store the daemon's data.
-  AC_MSG_CHECKING([for unit test root])
-  GUIX_TEST_ROOT="`pwd`/test-tmp"
-  AC_MSG_RESULT([$GUIX_TEST_ROOT])
+  GUIX_TEST_ROOT_DIRECTORY
+  GUIX_TEST_ROOT="$ac_cv_guix_test_root"
   AC_SUBST([GUIX_TEST_ROOT])
 
   AC_CONFIG_FILES([nix/scripts/list-runtime-roots],
diff --git a/configure.ac b/configure.ac
index 6f75fa3d7d1..940be768c7d 100644
--- a/configure.ac
+++ b/configure.ac
@@ -50,6 +50,8 @@ AC_SUBST([guix_localstatedir])
 AC_SUBST([guix_sysconfdir])
 AC_SUBST([guix_sbindir])
 
+GUIX_CHECK_FILE_NAME_LIMITS
+
 dnl We require the pkg.m4 set of macros from pkg-config.
 dnl Make sure it's available.
 m4_pattern_forbid([PKG_CHECK_MODULES])
diff --git a/m4/guix.m4 b/m4/guix.m4
index d4415598b04..445ce857dd6 100644
--- a/m4/guix.m4
+++ b/m4/guix.m4
@@ -1,5 +1,5 @@
 dnl GNU Guix --- Functional package management for GNU
-dnl Copyright © 2012, 2013, 2014 Ludovic Courtès <ludo@gnu.org>
+dnl Copyright © 2012, 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
 dnl Copyright © 2014 Mark H Weaver <mhw@netris.org>
 dnl
 dnl This file is part of GNU Guix.
@@ -162,3 +162,59 @@ AC_DEFUN([GUIX_CHECK_UNBUFFERED_CBIP], [
        ac_cv_guix_cbips_support_setvbuf=no
      fi])
 ])
+
+dnl GUIX_TEST_ROOT_DIRECTORY
+AC_DEFUN([GUIX_TEST_ROOT_DIRECTORY], [
+  AC_CACHE_CHECK([for unit test root directory],
+    [ac_cv_guix_test_root],
+    [ac_cv_guix_test_root="`pwd`/test-tmp"])
+])
+
+dnl 'BINPRM_BUF_SIZE' constant in Linux.  The Hurd has a limit
+dnl of about a page (see exec/hashexec.c.)
+m4_define([LINUX_HASH_BANG_LIMIT], 128)
+
+dnl Hardcoded 'sun_path' length in <sys/un.h>.
+m4_define([SOCKET_FILE_NAME_LIMIT], 108)
+
+dnl GUIX_SOCKET_FILE_NAME_LENGTH
+AC_DEFUN([GUIX_SOCKET_FILE_NAME_LENGTH], [
+  AC_CACHE_CHECK([the length of the installed socket file name],
+    [ac_cv_guix_socket_file_name_length],
+    [ac_cv_guix_socket_file_name_length="`echo -n "$guix_localstatedir/guix/daemon-socket/socket" | wc -c`"])
+])
+
+dnl GUIX_TEST_SOCKET_FILE_NAME_LENGTH
+AC_DEFUN([GUIX_TEST_SOCKET_FILE_NAME_LENGTH], [
+  AC_REQUIRE([GUIX_TEST_ROOT_DIRECTORY])
+  AC_CACHE_CHECK([the length of the socket file name used in tests],
+    [ac_cv_guix_test_socket_file_name_length],
+    [ac_cv_guix_test_socket_file_name_length="`echo -n "$ac_cv_guix_test_root/var/123456/daemon-socket/socket" | wc -c`"])
+])
+
+dnl GUIX_HASH_BANG_LENGTH
+AC_DEFUN([GUIX_HASH_BANG_LENGTH], [
+  AC_CACHE_CHECK([the length of a typical hash bang line],
+    [ac_cv_guix_hash_bang_length],
+    [ac_cv_guix_hash_bang_length=`echo -n "$storedir/aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa-bootstrap-binaries-0/bin/bash" | wc -c`])
+])
+
+dnl GUIX_CHECK_FILE_NAME_LIMITS
+dnl
+dnl GNU/Linux has a couple of silly limits that we can easily run into.
+dnl Make sure everything is fine with the current settings.
+AC_DEFUN([GUIX_CHECK_FILE_NAME_LIMITS], [
+  AC_REQUIRE([GUIX_SOCKET_FILE_NAME_LENGTH])
+  AC_REQUIRE([GUIX_TEST_SOCKET_FILE_NAME_LENGTH])
+  AC_REQUIRE([GUIX_HASH_BANG_LENGTH])
+
+  if test "$ac_cv_guix_socket_file_name_length" -ge ]SOCKET_FILE_NAME_LIMIT[; then
+    AC_MSG_ERROR([socket file name would exceed the maxium allowed length])
+  fi
+  if test "$ac_cv_guix_test_socket_file_name_length" -ge ]SOCKET_FILE_NAME_LIMIT[; then
+    AC_MSG_WARN([socket file name limit may be exceeded when running tests])
+  fi
+  if test "$ac_cv_guix_hash_bang_length" -ge ]LINUX_HASH_BANG_LIMIT[; then
+    AC_MSG_ERROR([store directory '$storedir' would lead to overly long hash-bang lines])
+  fi
+])
diff --git a/test-env.in b/test-env.in
index f66a0db555e..a7f506ec192 100644
--- a/test-env.in
+++ b/test-env.in
@@ -1,7 +1,7 @@
 #!/bin/sh
 
 # GNU Guix --- Functional package management for GNU
-# Copyright © 2012, 2013, 2014 Ludovic Courtès <ludo@gnu.org>
+# Copyright © 2012, 2013, 2014, 2015 Ludovic Courtès <ludo@gnu.org>
 #
 # This file is part of GNU Guix.
 #
@@ -52,6 +52,13 @@ then
     # Currently, in Nix builds, we're at ~106 chars...
     NIX_STATE_DIR="@GUIX_TEST_ROOT@/var/$$"
 
+    # We can't exit when we reach the limit, because perhaps the test doesn't
+    # actually rely on the daemon, but at least warn.
+    if test "`echo -n "$NIX_STATE_DIR/daemon-socket/socket" | wc -c`" -ge 108
+    then
+        echo "warning: exceeding socket file name limit; test may fail!" >&2
+    fi
+
     # The configuration directory, for import/export signing keys.
     NIX_CONF_DIR="@GUIX_TEST_ROOT@/etc"
     if [ ! -d "$NIX_CONF_DIR" ]