gnu: Add cinnamon.

* gnu/packages/cinnamon.scm (cinnamon): New variable.

1 files changed, 108 insertions, 0 deletions

diff --git a/gnu/packages/cinnamon.scm b/gnu/packages/cinnamon.scm
index 67f06156b17..2681f279e02 100644
--- a/gnu/packages/cinnamon.scm
+++ b/gnu/packages/cinnamon.scm
@@ -31,6 +31,7 @@
   #:use-module (guix build-system gnu)
   #:use-module (guix build-system meson)
   #:use-module (guix build-system pyproject)
+  #:use-module (guix build-system trivial)
   #:use-module (gnu packages)
   #:use-module (gnu packages admin)
   #:use-module (gnu packages autotools)
@@ -46,6 +47,7 @@
   #:use-module (gnu packages ghostscript)
   #:use-module (gnu packages gl)
   #:use-module (gnu packages glib)
+  #:use-module (gnu packages gstreamer)
   #:use-module (gnu packages gtk)
   #:use-module (gnu packages gnome)
   #:use-module (gnu packages gnuzilla)
@@ -63,9 +65,11 @@
   #:use-module (gnu packages pulseaudio)
   #:use-module (gnu packages python)
   #:use-module (gnu packages python-build)
+  #:use-module (gnu packages python-web)
   #:use-module (gnu packages python-xyz)
   #:use-module (gnu packages readline)
   #:use-module (gnu packages samba)
+  #:use-module (gnu packages time)
   #:use-module (gnu packages tls)
   #:use-module (gnu packages web)
   #:use-module (gnu packages window-management)
@@ -665,6 +669,110 @@ settings, themes, mouse settings, and startup of other daemons.")
 related packages.")
     (license license:gpl2+)))
 
+(define-public cinnamon
+  (package
+    (name "cinnamon")
+    (version "6.6.8")
+    (source (origin
+              (method git-fetch)
+              (uri (git-reference
+                     (url "https://github.com/linuxmint/cinnamon")
+                     (commit version)))
+              (file-name (git-file-name name version))
+              (sha256
+               (base32
+                "0g3n9aiyidi2fhjh8h3i2lb3gpif5kr2igsmzjvjzlvqapcyf8q7"))))
+    (build-system meson-build-system)
+    (arguments
+     (list
+      #:glib-or-gtk? #true
+      #:imported-modules `((guix build python-build-system)
+                           ,@%meson-build-system-modules)
+      #:phases
+      #~(modify-phases %standard-phases
+          (add-after 'unpack 'patch-install
+            (lambda* (#:key inputs #:allow-other-keys)
+              (substitute* "meson.build"
+                (("install_dir: '/',") "install_dir: prefix,"))
+              (substitute* "install-scripts/meson_update_icon_cache.py"
+                (("gtk-update-icon-cache") "true"))
+              (substitute* (append (find-files "files/usr/bin")
+                                   (find-files "files/usr/share" "\\.py$"))
+                ((".*octopi.*") "")
+                (("\"gsettings")
+                 (string-append "\""
+                                (search-input-file inputs "bin/gsettings")))
+                (("/usr/bin/passwd") "passwd")
+                (("/usr/bin/([a-z_-]*)" all command)
+                 (if (string-prefix? "cinnamon" command)
+                     (string-append #$output "/bin/" command)
+                     (search-input-file inputs
+                                        (string-append "/bin/" command))))
+                (("/usr/share") (string-append #$output "/share")))
+              (rename-file "files/usr/bin" "files/bin")
+              (rename-file "files/usr/share" "files/share")
+              (rmdir "files/usr")
+              (substitute* "files/share/cinnamon/cinnamon-settings/bin/capi.py"
+                (("(f?)\"/usr/lib/([^\"]*)\"" all f lib)
+                 (string-append f "\"/run/current-system/profile/lib/" lib "\","
+                                f "\"/usr/lib/" lib "\"")))))
+          (add-after 'install 'add-install-to-pythonpath
+            (@@ (guix build python-build-system) add-install-to-pythonpath))
+          (add-after 'add-install-to-pythonpath 'wrap-for-python
+            (@@ (guix build python-build-system) wrap))
+          (add-after 'wrap-for-python 'wrap-gi
+            (lambda _
+              (define gi-typelib-path (getenv "GI_TYPELIB_PATH"))
+              (for-each
+               (lambda (program)
+                 (unless (wrapped-program? program)
+                   (wrap-program program
+                     `("GI_TYPELIB_PATH" ":" prefix (,gi-typelib-path)))))
+               (find-files (string-append #$output "/bin"))))))))
+    (inputs (list cinnamon-control-center
+                  cinnamon-desktop
+                  cinnamon-menus
+                  cjs
+                  cups-minimal
+                  gcr-3
+                  gsound
+                  gstreamer
+                  libgnomekbd
+                  libnotify
+                  libsecret
+                  libxapp
+                  network-manager
+                  muffin
+                  polkit
+                  python-wrapper
+                  python-dbus
+                  python-libsass
+                  python-pam
+                  python-pycairo
+                  python-pexpect
+                  python-pillow
+                  python-psutil
+                  python-pytz
+                  python-pygobject
+                  python-requests
+                  python-setproctitle
+                  python-tinycss2
+                  python-xapp
+                  python-xlrd
+                  timezonemap
+                  xdg-utils))
+    (native-inputs (list gettext-minimal
+                         `(,glib "bin")
+                         gobject-introspection
+                         intltool
+                         pkg-config))
+    (home-page "https://github.com/linuxmint/cinnamon/")
+    (synopsis "Graphical desktop environment")
+    (description
+     "Cinnamon is a desktop environment reminiscent of ye olde GNOME 2,
+with its underlying technology forked from modern GNOME.")
+    (license (list license:gpl2+))))
+
 (define-public muffin
   (package
     (name "muffin")